#!perl

our $DATE = '2020-01-31'; # DATE
our $VERSION = '0.730'; # VERSION

use 5.010;
use strict;
use warnings;
use Log::ger;

use App::PMUtils;
use File::Which;
use IO::Prompt::I18N qw(confirm);
use Module::Path::More qw(module_path);
use IPC::System::Options qw(readpipe);
use Perinci::CmdLine::Any;

our %SPEC;
$SPEC{pmuninst} = {
    v => 1.1,
    summary => 'Uninstall an installed Perl module (using cpanm --uninstall)',
    args => {
        module => $App::PMUtils::arg_module_multiple,
        uninstall_rdeps => {
            schema => 'bool',
            summary => 'Also uninstall dists which depends on the module(s) being uninstalled',
            cmdline_aliases => {R=>{}},
        },
        confirm_yes => {
            schema => ['bool', is=>1],
            cmdline_aliases => {y=>{}},
        },
    },
    deps => {
        prog => 'cpanm',
    },
};
sub pmuninst {
    use experimental 'smartmatch';

    my %args = @_;
    my $mods = $args{module};

    my $lcpan_is_available;
    my @rmods;
    {
        last unless which "lcpan";
        $lcpan_is_available++;
        require JSON::MaybeXS;
        my $lrres = readpipe(
            {log=>1, die=>1},
            "lcpan", "rdeps", "--phase", "ALL", "--rel", "requires", "--json",
            "-l", 2, # limit to this level for now, for speed
            "--no-naked-res",
            @$mods
        );
        $lrres = JSON::MaybeXS->new->decode($lrres);
        for (@{ $lrres->[2] }) {
            my $mod = $_->{dist}; $mod =~ s/^\s+//; $mod =~ s/-/::/g;
            next unless module_path(module=>$mod);
            push @rmods, $mod unless $mod ~~ @$mods;
        }
        @rmods = sort @rmods;
    }

    if ($args{uninstall_rdeps}) {
        return [412, "lcpan is required to find reverse deps"]
            unless $lcpan_is_available;
        if (@rmods && !$args{confirm_yes}) {
            return [200, "Cancelled"] unless
                confirm("These modules will also be uninstalled: ".
                        join(", ", @rmods) . ", are you sure?");
        }
        push @$mods, @rmods;
    } else {
        print "Warning: The following module(s) depend on ".
            (@$mods > 1 ? "(".join(", ", @$mods).")" : $mods->[0]).
            " and may not work aftewards: ".join(", ", @rmods)."\n\n"
            if @rmods;
    }

    for my $mod (@$mods) {
        $mod =~ s/\.pm$//; $mod =~ s!/!::!g; # convenience
        system(
            "cpanm", "--uninstall",
            ($args{confirm_yes} ? ("-f") : ()),
            $mod,
        );
    }
    [200, "OK"]; # XXX check/accumulate success status
}

Perinci::CmdLine::Any->new(
    url => '/main/pmuninst',
    read_config => 0,
    read_env => 0,
)->run;

# ABSTRACT: Uninstall an installed Perl module (using cpanm --uninstall)
# PODNAME: pmuninst

__END__

=pod

=encoding UTF-8

=head1 NAME

pmuninst - Uninstall an installed Perl module (using cpanm --uninstall)

=head1 VERSION

This document describes version 0.730 of pmuninst (from Perl distribution App-PMUtils), released on 2020-01-31.

=head1 SYNOPSIS

 % pmuninst App::Stopwatch

=head1 OPTIONS

C<*> marks required options.

=head2 Main options

=over

=item B<--confirm-yes>, B<-y>

=item B<--module-json>=I<s>

See C<--module>.

=item B<--module>=I<s@>*

Can be specified multiple times.

=item B<--uninstall-rdeps>, B<-R>

Also uninstall dists which depends on the module(s) being uninstalled.

=back

=head2 Output options

=over

=item B<--format>=I<s>

Choose output format, e.g. json, text.

Default value:

 undef

=item B<--json>

Set output format to json.

=item B<--naked-res>

When outputing as JSON, strip result envelope.

Default value:

 0

By default, when outputing as JSON, the full enveloped result is returned, e.g.:

    [200,"OK",[1,2,3],{"func.extra"=>4}]

The reason is so you can get the status (1st element), status message (2nd
element) as well as result metadata/extra result (4th element) instead of just
the result (3rd element). However, sometimes you want just the result, e.g. when
you want to pipe the result for more post-processing. In this case you can use
`--naked-res` so you just get:

    [1,2,3]


=back

=head2 Other options

=over

=item B<--help>, B<-h>, B<-?>

Display help message and exit.

=item B<--version>, B<-v>

Display program's version and exit.

=back

=head1 COMPLETION

This script has shell tab completion capability with support for several
shells.

=head2 bash

To activate bash completion for this script, put:

 complete -C pmuninst pmuninst

in your bash startup (e.g. F<~/.bashrc>). Your next shell session will then
recognize tab completion for the command. Or, you can also directly execute the
line above in your shell to activate immediately.

It is recommended, however, that you install modules using L<cpanm-shcompgen>
which can activate shell completion for scripts immediately.

=head2 tcsh

To activate tcsh completion for this script, put:

 complete pmuninst 'p/*/`pmuninst`/'

in your tcsh startup (e.g. F<~/.tcshrc>). Your next shell session will then
recognize tab completion for the command. Or, you can also directly execute the
line above in your shell to activate immediately.

It is also recommended to install L<shcompgen> (see above).

=head2 other shells

For fish and zsh, install L<shcompgen> as described above.

=head1 HOMEPAGE

Please visit the project's homepage at L<https://metacpan.org/release/App-PMUtils>.

=head1 SOURCE

Source repository is at L<https://github.com/perlancar/perl-App-PMUtils>.

=head1 BUGS

Please report any bugs or feature requests on the bugtracker website L<https://rt.cpan.org/Public/Dist/Display.html?Name=App-PMUtils>

When submitting a bug or request, please include a test-file or a
patch to an existing test-file that illustrates the bug or desired
feature.

=head1 SEE ALSO

L<pm-uninstall> from L<App::pmuninstall>

=head1 AUTHOR

perlancar <perlancar@cpan.org>

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2020, 2019, 2018, 2017, 2016, 2015, 2014 by perlancar@cpan.org.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
