#!perl

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2020-12-01'; # DATE
our $DIST = 'App-DiffDocText'; # DIST
our $VERSION = '0.002'; # VERSION

use 5.010001;
use strict;
use warnings;
use Log::ger;
#use Log::ger::Screen;

use Getopt::Long ();
use CLI::MetaUtil::Getopt::Long qw(GetOptionsCLIWrapper);

my @files;
Getopt::Long::Configure("gnu_getopt", "no_ignore_case", "pass_through");

my $fail;

GetOptionsCLIWrapper(
    cli => 'diff',
    add_opts => {
        '<>' => sub {
            my $filename = $_[0];
            unless (-f $filename) {
                warn "diff-doc-text: No such file or not a file: '$filename'\n";
                $fail++;
                return;
            }

            require App::OfficeUtils;
            my $res = App::OfficeUtils::officewp2txt(
                input_file => $filename,
                fmt => 1,
            return_output_file => 1,
            );
            my $file;
            if ($res->[0] == 304) {
                $file = $_[0];
            } elsif ($res->[0] == 200) {
                $file = $res->[2];
            } else {
                die "Can't convert doc '$_[0]' to text: $res->[0] - $res->[1]";
            }
            push @CLI::MetaUtil::Getopt::Long::cli_argv, $file;
        },
    },
);

exit 1 if $fail;

require File::Which;
my $diff_cmd =
    $ENV{DIFF_DOC_TEXT_DIFF_CMD} //
    (File::Which::which("diffwc") ? "diffwc" : undef) // "diff";

require IPC::System::Options;
IPC::System::Options::system(
    {log=>1},
    $diff_cmd, @ARGV,
);

# ABSTRACT: Diff the text of two Office word-processor documents (.doc, .docx, .odt, etc)
# PODNAME: diff-doc-text

__END__

=pod

=encoding UTF-8

=head1 NAME

diff-doc-text - Diff the text of two Office word-processor documents (.doc, .docx, .odt, etc)

=head1 VERSION

This document describes version 0.002 of diff-doc-text (from Perl distribution App-DiffDocText), released on 2020-12-01.

=head1 SYNOPSIS

Use like you would use the Unix command B<diff>:

 % diff-doc-text [options] <FILE>...

=head1 DESCRIPTION

This is a wrapper for the Unix command B<diff>. It assumes that each file is an
Office word-processor documents (.doc, .docx, .odt, etc) and tries to convert
the file to plaintext first. It then passes the converted files to C<diff>.

=head1 DIFF_DOC_TEXT_DIFF_CMD

String. Can be used to set path to diff command. The defaultl is L<diffwc> if
available in PATH, or C<diff>.

=head1 ENVIRONMENT

=head1 HOMEPAGE

Please visit the project's homepage at L<https://metacpan.org/release/App-DiffDocText>.

=head1 SOURCE

Source repository is at L<https://github.com/perlancar/perl-App-DiffDocText>.

=head1 BUGS

Please report any bugs or feature requests on the bugtracker website L<https://rt.cpan.org/Public/Dist/Display.html?Name=App-DiffDocText>

When submitting a bug or request, please include a test-file or a
patch to an existing test-file that illustrates the bug or desired
feature.

=head1 SEE ALSO

Unix command L<diff>.

L<App::OfficeUtils> and the included CLI L<doc2txt>.

=head1 AUTHOR

perlancar <perlancar@cpan.org>

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2020 by perlancar@cpan.org.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
